1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

@echo off

echo 百度网盘智能看图卸载工具
echo 请以管理员身份运行此脚本！
echo.

echo 正在删除注册表项...
:: 删除HKEY_CLASSES_ROOT\BaiduNetdiskImageViewerAssociations
taskkill /f /im BaiduNetdisk.exe >nul 2>nul
reg delete "HKEY_CLASSES_ROOT\BaiduNetdiskImageViewerAssociations" /f >nul 2>nul

:: 删除HKEY_CURRENT_USER\Software\Baidu\BaiduNetdiskImageViewer
reg delete "HKEY_CURRENT_USER\Software\Baidu\BaiduNetdiskImageViewer" /f >nul 2>nul

:: 删除HKEY_CURRENT_USER\Software\RegisteredApplications\BaiduNetdiskImageViewer
reg delete "HKEY_CURRENT_USER\Software\RegisteredApplications" /v "BaiduNetdiskImageViewer" /f >nul 2>nul

echo.
echo 正在删除文件夹...
:: 安装位置不确定，但开始菜单中一定有快捷方式，通过快捷方式读取百度网盘的安装位置
for /f "usebackq delims=" %%I in (`
  powershell -NoLogo -NoProfile -Command ^
    "(New-Object -COM WScript.Shell).CreateShortcut('%APPDATA%\Microsoft\Windows\Start Menu\Programs\百度网盘\百度网盘.lnk').TargetPath"
`) do (
  set "installDir=%%~dpI"
)
set "installDir=%installDir:~0,-1%"
echo 百度网盘安装位置：%installDir%

:: 查找并删除百度网盘根目录中的ImageViewer文件夹
for /d %%i in ("%installDir%", "C:\Program Files\Baidu\BaiduNetdisk") do (
  if exist "%%i\module\ImageViewer" (
    rd /s /q "%%i\module\ImageViewer"
  )
)

echo.
echo 百度网盘智能看图卸载完成！
pause