没什么需要特别说明说的，有疑问就看msdn吧，窗体上两个按钮，一个treeview：
Option Explicit
Private Declare Function SetWindowLong Lib "user32" _
 Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, _
 ByVal dwNewLong As Long) As Long
Private Declare Function GetWindowLong Lib "user32" _
 Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) _
 As Long

Private Const TVS_NOTOOLTIPS = &H80
Private Const GWL_STYLE = (-16)

Private Sub ShowToolTips(TreeView As TreeView)
  Dim nStyles As Long
 
  With TreeView
    nStyles = GetWindowLong(.hwnd, GWL_STYLE)
    nStyles = nStyles And (Not TVS_NOTOOLTIPS)
    SetWindowLong .hwnd, GWL_STYLE, nStyles
  End With
End Sub

Private Sub HideToolTips(TreeView As TreeView)
  Dim nStyles As Long
 
  With TreeView
    nStyles = GetWindowLong(.hwnd, GWL_STYLE)
    nStyles = nStyles Or TVS_NOTOOLTIPS
    SetWindowLong .hwnd, GWL_STYLE, nStyles
  End With
End Sub

Private Sub Command1_Click()
    HideToolTips Me.TreeView1
End Sub

Private Sub Command2_Click()
    ShowToolTips Me.TreeView1
End Sub

Private Sub Form_Load()
    Command1.Caption = "隐藏ToolTips"
    Command2.Caption = "显示ToolTips"
    Dim i As Long
    For i = 1 To 100
    Me.TreeView1.Nodes.Add , , , "hello this is test hello this is test hello this is test" & CStr(i)
    Next
End Sub