Не большой пример для начинающих ПЛИСоводов, как подключить к ПЛИС (ALTERA Cyclon 4) клавиатуру с интерфейсом PS/2, а так же компьютер по интерфейсу RS232 (он же COM-порт).

Начнём с главного, необходимо обеспечить правильное аппаратное подключение, что бы ничего не спалить. Мне в этом отношении повезло, наши друзья китайцы, всё сделали за меня. Далее привожу схему, которую вам следует всё же проверить, так как это как раз то место, где вас может ждать сюрприз (может ещё где то, но не фатальный). Так как я сам начинающий в этом вопросе, будьте внимательны.

В настройках программы Quartus 2, настроить соответствующие ножки микросхемы как 3.3-V LVTTL. Программа выдаёт предупреждение, но в документации указано, что при таком конфигурации (пишу по памяти) ограничительные диоды подключены, то есть всё правильно. Точно так же настраиваются ножки микросхемы идущие на приёмопередатчик. Сразу привожу схему для приёмопередатчика. (Смотрите документацию на ваши микросхемы и будьте внимательны.)

Алгоритм работы устройства следующий. Принимаемые данные от клавиатуры записываются в буфер. Если заполнение буфера превышает некий предел, и все данные из буфера прочитаны, то начинаем заполнение буфера с начала. По готовности данных инициируем отправку этих данных в компьютер, где в любой программе, например гипертерминал или Геркулес, можно увидеть принятый от клавиатуры скан-код. Устройство работает на частоте 50МГц, приёмопередатчик настроен на частоту обмена 19200 бит/сек. Код достаточно простой и короткий, с комментариями. Кстати да, код писал не я, а Никлаус Вирт (см. проект Оберон), я позаимствовал для обучения. Так же код для кнопки я взял из видео-уроков ютуб-канала ПЛИСоводство. Схему для кнопки не привожу, этого добра хватает в интернете. Да и кнопка эта (сброс) не очень нужна. Далее код.

`timescale 1ns / 1ps
/* Модуль для проверки подключения клавиатуры
	и ПК по интерфейсу RS232 */
module KlMon((* chip_pin = "114" *) output TxD,

             (* chip_pin = "115" *) input RxD, // не используется

             (* chip_pin = "25"  *) input Res,
			 (* chip_pin = "23"  *) input clk, // 50МГц

			 (* chip_pin = "119" *) input wire PS2C,  // клавиатура
			 (* chip_pin = "120" *) input wire PS2D);


wire [7:0] dataTx, dataKbd, eventKbd;
wire startTx, rdyTx, rdyKbd, doneKbd, rst;

reg [7:0] temp;

reg Q0, Q1, fRdyKbd, fTx;  // синхронизация и детектор фронта


assign eventKbd = ~Q1 & Q0;
assign dataTx = temp;
assign doneKbd = fRdyKbd;

/* Начнём передачу, если передатчик готов и есть данные.
	  После начала передачи уйдёт готовность. */
assign startTx = fTx & rdyTx;

/* Кнопка сброс */
Button BT_R(.TTrigQ(rst), .X(Res), .C(clk));

RS232T transmitter(.clk(clk), .rst(rst), .start(startTx),
   .data(dataTx), .TxD(TxD), .rdy(rdyTx)); 

PS2 kbd(.clk(clk), .rst(rst), .done(doneKbd), .rdy(rdyKbd), .shift(),
   .data(dataKbd), .PS2C(PS2C), .PS2D(PS2D));

always @ (posedge clk)
begin
/* Фиксируем событие от клавиатуры */
	Q0 <= rdyKbd; Q1 <= Q0;

	if (rst)
	begin
		temp <= 8'd0;
		fTx <= 1'd0;
		fRdyKbd <= 1'd0;
	end
	else
	begin
/* Если готовы данные от клавиатуры, прочтём. */
		temp <= rdyKbd ? dataKbd : temp;
	
/* Сообщим модулю клавиатуры что данные прочитаны,
	  пусть переставит указатеь в очереди. */
		fRdyKbd <= rdyKbd;

/* Если нажата клавиша — ставим флаг.
       Если началась передача — сбрасываем. */
		fTx <= eventKbd ? 1'd1 : (startTx ? 1'd0 : fTx);
	end
end
	
endmodule

/* Код для кнопок. Взял у Ютуб-канала ПЛИСоводство  */
module Button(output reg TTrigQ,
			  input X,
			  input C);

	initial TTrigQ <= 1'd1;

	reg [18:0]CTQ; // счётчик подавления дребезга контактов
	reg XQ, RSTrigQ, BQ;

	wire FY = !RSTrigQ & BQ; // схема выделения фронта

	always @(posedge C)
	begin
		XQ <= !X;
		/* &CTQ - все биты счётчика равны единице, т.е. максимум, даёт единицу
	      |CTQ - все биты счётчика равны нулю, т.е. минимум, даёт ноль	*/
		if (XQ & ~&CTQ) CTQ <= CTQ + 1'd1;
			else if (!XQ & |CTQ) CTQ <= CTQ - 1'd1;

		if (&CTQ) RSTrigQ <= 1'd1; // счётчик досчитал до макс., запоминаем 1
			else if (~|CTQ) RSTrigQ <= 1'd0; // досчитал до мин., запоминаем 0

		BQ <= RSTrigQ;
		TTrigQ <= FY;
	end

endmodule

`timescale 1ns / 1ps  // NW 20.10.2012
// PS2 receiver for keyboard, 8 bit data

/* Автор Никлаус Вирт, я косметически подправил для своих нужд. */
module PS2(
    input clk, rst,
    input done,   // "byte has been read"
    output rdy,   // "byte is available"
    output shift, // shift in, tramsmitter
    output [7:0] data,
    input PS2C,   // serial input
    input PS2D);
	 
reg Q0, Q1;  // synchronizer and falling edge detector
reg [10:0] shreg;
reg [3:0] inptr, outptr;
reg [7:0] fifo [15:0];  // 16 byte buffer
wire endbit;

assign endbit = ~shreg[0];  //start bit reached correct pos
assign shift = Q1 & ~Q0;
assign data = fifo[outptr];
assign rdy = ~(inptr == outptr); // Флаг наличия принятых данных

always @ (posedge clk) begin
/* Фиксируем задний фронт (спад) */
  Q0 <= PS2C; Q1 <= Q0;

/* Если сброс или конец посылки, установим все единицы;
       иначе, если зафиксирован спад, заносим данные в
		   старший разряд сдвигового регистра, иначе храним состояние. */
  shreg <= (rst | endbit) ? 11'h7FF :
    shift ? {PS2D, shreg[10:1]} : shreg;

/* Указатель выхода. Если сброс, то ноль, иначе
	    если прочитано значение и есть ещё, перемещаем выход */
  outptr <= rst ? 1'd0 : rdy & done ? outptr + 1'd1 : outptr;
  inptr <= rst ? 1'd0 : endbit ? inptr + 1'd1 : inptr;

/* Если принят последний бит, читаем сдвиговый регистр в очередь. */
  if (endbit) fifo[inptr] <= shreg[8:1];

/* Всё прочитано и выходной указатель близок к пределу,
     начнём буфер  с начала. */
  if (!rdy & (outptr >= 4'd14))
     begin
	      inptr <= 4'd0;
          outptr <= 4'd0;
	  end
end	 
endmodule

`timescale 1ns / 1ps  // NW 4.5.09 / 15.8.10 / 15.11.10
// RS232 transmitter for 19200 bps, 8 bit data, без чётности/нечётности
// clock is 50 MHz; 50000 / 2604 = 19.2 KHz

/* Автор Никлаус Вирт, я косматически подправил для своих нужд. */
module RS232T(
    input clk, rst,
    input start, // request to accept and send a byte
    input [7:0] data,
    output rdy,
    output TxD);

wire endtick, endbit;
wire [11:0] limit;
reg run;
reg [11:0] tick;
reg [3:0] bitcnt;
reg [8:0] shreg;

assign limit = 12'd2604; // Длина бита в тактах, при данной скорости обмена
assign endtick = tick == limit; // Флаг конца бита
assign endbit = bitcnt == 4'd9; // Флаг конца битовой последовательности
assign rdy = ~run;     // Не работаем? установим флаг готовность к передаче.
assign TxD = shreg[0]; // Выдаём в линию младший бит сдвигового регистра

always @ (posedge clk) begin

/* Если сброс, или конец тика и конец бита, то ноль,
       иначе проверяем старт.
		Если старт, то еденица, иначе храним значение.	*/
  run <= (rst | endtick & endbit) ? 1'd0 : start ? 1'd1 : run;

/* Пока run и не конец тика, инкремент переменной тик,
        иначе ноль. */
  tick <= (run & ~endtick) ? tick + 1'd1 : 1'd0;

/* Конец тика и не конец бита, увеличиваем счетчик бит,
		Иначе, если конец тика и конец бита, то ноль,
	      иначе храним значение. */
  bitcnt <= (endtick & ~endbit) ? bitcnt + 1'd1 :
    (endtick & endbit) ? 1'd0 : bitcnt;

/* В сдвиговом регистре, если сброс, единица (высокий на линии)
	   иначе, есть старт, выдаём стартовый бит
		  (ноль в младшем разряде сдвигового регистра),
              иначе, если конец тика, сдвиг вправо (в сторону мл. разряда),
                       иначе храним значение. */
  shreg <= (rst) ? 1'd1 : start ? {data, 1'b0} :
    endtick ? {1'b1, shreg[8:1]} : shreg;
end

endmodule

Вот и всё. Кто гадал как такое реализовать, не благодарите. Я всё это включал, работает, проверено.

PS: Код на verilog, в настройках оформления кода почему то его нет. Указал VHDL.