Power BI 由于缺少事实数据，X轴日期不连续

当前效果和问题

上图效果中日期不连续，因为缺少数据，想要让没有数据的日期段用0填充起来，但是不得法

涉及的DAX公式

Per.CallBack.bySelectDate = DIVIDE([Qty.In.GP.CallBack.bySelectDate] , [Qty.NeedCallBack.GP.bySelectDate])


Qty.In.GP.CallBack.bySelectDate = 
//需要回拨且已回拨数量
CALCULATE(
    [Qty.In.GP.BySelectDate],
   'F_Call_Log'[处理状态] in {"已留言","振铃未接听","排队放弃"},
   'F_Call_Log'[备注] <> ""
)


Qty.NeedCallBack.GP.bySelectDate = [Qty.In.GP.CallBack.bySelectDate] + [Qty.In.GP.NonCallBack.bySelectDate] ）


Qty.In.GP.NonCallBack.bySelectDate = 
//轮询呼入，未接通需回拨数量
CALCULATE(
    [Qty.In.GP.BySelectDate],
   'F_Call_Log'[处理状态] in {"已留言","振铃未接听","排队放弃"},
   'F_Call_Log'[备注] = ""
)


Qty.In.GP.BySelectDate = 
CALCULATE(
    [Qty.In.bySelectDate],
    F_Call_Log[CallType] in { "Group" }
)


Qty.In.bySelectDate = 
CALCULATE(
    [Qty.In],
    FILTER('DateTable.MonthWeek',AND( [Date] >= [SelectDate.Start], [Date] <= [SelectDate.End] ) )
)

模型说明

1，我的日期筛选不是用的常规方式，我建立了两个表 ‘DateTable.Slect.End’ ，‘DateTable.Slect.Start’

2， ‘DateTable.MonthWeek’ 用的是老师的化钻取为点选的方式

3. 模型连线如下

失败的尝试

问题的原因是因为数据的缺少，导致DIVIDE 算出来的是空值，我尝试在DIVIDE之外使用0去填充，但是没达到我想要的效果，多半是因为我所使用的日期筛选方法落下的坑，但不知道怎么解决

尝试解法一，很明显不合要求

Per.CallBack.bySelectDate = 
VAR v_SelDate = SELECTEDVALUE('DateTable.MonthWeek'[Date])
VAR v_ActualPer = DIVIDE([Qty.In.GP.CallBack.bySelectDate] , [Qty.NeedCallBack.GP.bySelectDate])
RETURN
IF(
    ISBLANK(v_ActualPer) ,
    0,
    v_ActualPer
)

尝试解法二，又回到了最开始的状态

Per.CallBack.bySelectDate = 
VAR v_SelDate = SELECTEDVALUE('DateTable.MonthWeek'[Date])
VAR v_ActualPer = DIVIDE([Qty.In.GP.CallBack.bySelectDate] , [Qty.NeedCallBack.GP.bySelectDate])
RETURN
IF(
    ISBLANK(v_ActualPer) && AND(v_SelDate >= [SelectDate.Start] , v_SelDate<= [SelectDate.End]) ,
    0,
    v_ActualPer
)

最终的解决方法

解决方法三：divide 参数部分加0

Per.CallBack.bySelectDate = DIVIDE([Qty.In.GP.CallBack.bySelectDate] +0 , [Qty.NeedCallBack.GP.bySelectDate] +0)

结尾总结

造成这个问题是一个巧合，以下两者因素碰在一起就会出现问题

对时间列的筛选是DAX 公式判断
X轴用的不是时间列（比如这里用的item 其实是为了使用 “化钻取为点选” 而造的列）

当满足上面两个因素的时候，对于无数据项目的显示会造成X轴在显示时突破我们设定的时间边界

解决的方法有两种

是使用时间列做X轴，但是大部分情况下不使用时候列是有原因的
在DAX公式的合适位置 +0 ，以达到显示空值的效果

本例解法一中，+0 相当于显示空值的操作，我们要做的是 +0，但是要保持住DAX公式里的筛选，要在外层环境与实际计算公式之间去加，这个列子就是在分子/分母度量的计算上下文（内层计算）和DIVIDE计算上下文（外层计算）之间去加

推荐订阅源

issue – Ed_'s Blog