背景
Windows 11 家庭版官方不支持 Hyper-V，但系统镜像中实际包含了 Hyper-V 的组件包，只是被隐藏了。通过本教程可以强制启用。
一、准备工作
1.1 检查硬件支持
在任务管理器查看是否已开启虚拟化
确保显示”固件中已启用虚拟化“。如果没有，需先进入 BIOS 开启 Intel VT-x 或 AMD SVM。
二、修复组件存储（重要）
在安装 Hyper-V 之前，先修复可能存在的系统组件损坏，避免出现 0x8007371B 等错误。
以管理员身份打开 CMD，依次执行：
2.1 修复 DISM 组件存储
DISM /Online /Cleanup-Image /RestoreHealth
耗时约 10-30 分钟，请耐心等待。如果卡住不动，不要强制关闭。
2.2 修复系统文件
sfc /scannow扫描并修复损坏的系统文件，一般 5-15 分钟完成。
2.3 重启电脑
修复完成必须重启才能使更改生效。
三、安装 Hyper-V
3.1 创建安装脚本
新建一个 .bat 文件（例如 hyper-v-home.bat），内容如下：
@echo off
setlocal EnableDelayedExpansion
title Hyper-V Home Setup
:: === Auto-elevate (copy self to temp, VBS launch, avoid Chinese path issues) ===
fltmc >nul 2>&1 || (
echo Requesting admin rights...
copy "%~f0" "%temp%\hv-setup.bat" /y >nul
set "vbs=%temp%\hv-elevate.vbs"
>"!vbs!" echo Set UAC = CreateObject^("Shell.Application"^)
>>"!vbs!" echo UAC.ShellExecute "cmd", "/c ""%temp%\hv-setup.bat""", "", "runas", 1
cscript //nologo "!vbs!"
del "!vbs!"
exit
)
:: === Main setup ===
echo.
echo ============================================
echo Win11 Home Hyper-V Setup
echo ============================================
echo.
echo [1/4] Configuring registry...
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\SideBySide\Configuration" /v "PreferSystemPolicy" /t REG_DWORD /d 1 /f >nul 2>&1
echo [1/4] Done.
echo.
echo [2/4] Installing Hyper-V packages...
set "pkg=0"
for /f "delims=" %%i in ('dir /b "%SystemRoot%\servicing\Packages\*Hyper-V*.mum" 2^>nul') do (
set "pkg=1"
echo %%i
dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i" >nul 2>&1
)
if "!pkg!"=="0" echo No local packages found, skipping.
echo [2/4] Done.
echo.
echo [3/4] Enabling Hyper-V platform (1-3 minutes, please wait)...
dism /online /enable-feature /featurename:Microsoft-Hyper-V-All /norestart /LimitAccess /ALL
echo [3/4] Done.
echo.
echo [4/4] Verifying...
dism /online /get-featureinfo /featurename:Microsoft-Hyper-V-All 2>nul | findstr /i "Enabled 已启用" >nul && (
echo SUCCESS - Hyper-V is now enabled.
) || (
echo Some features pending - restart and re-run this script.
)
echo.
echo Press any key to restart, or close to restart later...
pause >nul
shutdown /r /t 0
3.2 运行脚本
双击 hyper-v-home.bat，在弹出的 UAC 窗口点击”是”，脚本将自动完成所有步骤并提示重启。
四、常见错误解决
4.1 错误 0x8007371B
Windows 无法完成请求的更改。
一个或多个要求的事务成员不存在。
错误代码: 0x8007371B原因： Windows 组件存储（C:\Windows\WinSxS）损坏或存在不完整的包文件。
解决：
- 执行本文第二章节的修复步骤
- 重启后重新运行脚本
- 如果仍报错，检查 Hyper-V 包是否存在：
dir /b %SystemRoot%\servicing\Packages\*Hyper-V*.mum- 无输出： 系统镜像中缺少 Hyper-V 离线包，此方法不适用
- 有输出： 找到报错的那个包名，手动安装定位问题：
dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\<报错的包名>"4.2 DISM 修复本身报错
如果 DISM /RestoreHealth 也失败，需要用 Windows 11 安装镜像作为修复源：
DISM /Online /Cleanup-Image /RestoreHealth /Source:WIM:<镜像盘符>:\sources\install.wim:<索引号> /LimitAccess可通过微软官网下载 Windows 11 媒体创建工具获取安装镜像。
4.3 错误 0x800f0954
此错误表示系统尝试从 Windows Update 下载文件但被阻止，通常不需要处理——脚本中已经配置了注册表禁止走 Windows Update，这也是预期行为。
4.4 Hyper-V 平台选项灰色/不可用
重启后进入 BIOS，确认以下选项已开启：
- Intel VT-x / AMD SVM
- Intel VT-d（可选，用于 PCIe 直通）
4.5 Hyper-V 平台选项灰色/不可用
如果还是有问题，在 PowerShell 中执行：
bcdedit /set hypervisorlaunchtype auto然后重启电脑
五、验证安装
重启后，在 PowerShell 中执行：
Get-WindowsOptionalFeature -Online -FeatureName Microsoft-Hyper-V-All如果 State 显示为 Enabled，说明安装成功。
也可以在开始菜单搜索”Hyper-V 管理器“来创建和管理虚拟机。
六、卸载 Hyper-V
如果需要卸载，以管理员身份执行：
dism /online /disable-feature /featurename:Microsoft-Hyper-V-All /norestart重启后即可完全移除。
原创文章，作者：陌涛，如若转载，请注明出处：https://imotao.com/9356.html
赞 (0)
打赏
微信扫一扫
支付宝扫一扫