You mind updating it to version 5.0.0? EDIT: Which would involve getting python-sepaxml from 2.6.1 to at least 2.7, but it's orphaned as well :/

Hi, this pkgbuild currently won't build. I rewrote the package a bit:

# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
# Maintainer: Mikhaul f. Shiryaev <mr dot felixoid at gmail dot com>

pkgname=python-fints
pkgver=4.2.4
pkgrel=1
pkgdesc="Minimal pure-python FinTS (formerly known as HBCI) implementation"
arch=(any)
url="https://github.com/raphaelm/python-fints"
license=('LGPL-3.0-only')
depends=(
  python
  python-bleach
  python-mt-940
  python-requests
  python-sepaxml
)
makedepends=(
  git
  python-build
  python-installer
  python-setuptools
)
checkdepends=(
  python-pytest
  python-pytest-mock
)
source=("git+${url}.git#tag=v${pkgver}")
sha512sums=('2090287b89a2bf02f26e96c765724b300c869e74043cf4d0c955c9a5b86e6bf3919808f125c1fc22a50a7d559572912da9ca68476a3b37e2b95f5bbf78d176c7')

build() {
  cd ${pkgname}
  python -m build --wheel --no-isolation
}

check() {
  cd ${pkgname}
  PYTHONPATH=. pytest
}

package() {
  cd ${pkgname}
  python -m installer --destdir="${pkgdir}" "dist/fints-${pkgver}-py3-none-any.whl"
}

# vim:set ts=2 sw=2 et: