You are right, I must have misremembered something 🤦

@micwoj92

'!check' isn't a valid option, from a TODO it seems they suggest to:

The solution is to disable the check() test invocation or just to fix the test

So in this case, you might as well just disable the check (since it's not ran anyways)

Please don't use BUILDENV+=('!check'). Use options=('!check) instead.

Once Pandas 2 is in the official repos, this can be released:

diff --git a/PKGBUILD b/PKGBUILD
index 730c42d..ca220fa 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -3,8 +3,8 @@

 _name=plotnine
 pkgname=python-$_name
-pkgver=0.12.3
-pkgrel=2
+pkgver=0.13.0
+pkgrel=1
 pkgdesc='A grammar of graphics for python'
 arch=(any)
 url="https://github.com/has2k1/$_name"
@@ -12,11 +12,10 @@ license=('MIT')
 depends=(
    python
    'python-matplotlib>=3.6.0'
-   'python-mizani<=0.11.0'
+   'python-pandas>=2.1.0'
+   'python-mizani>=0.11.0'
    'python-numpy>=1.23.0'
-   'python-pandas>=1.5.0'
-   'python-patsy>=0.5.1'
-   'python-scipy>=1.5.0'
+   'python-scipy>=1.7.0'
    'python-statsmodels>=0.14.0'
 )

@@ -44,7 +43,7 @@ checkdepends=(
 )

 source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
-sha256sums=('a38dcb3607fc003c1e59ae0c9d535dae7817650d1cbc2e56e56e5b3de88dfe99')
+sha256sums=('f598c3dad88912f503698d562329cdbfedc42f9661f429053f8d5cb75f24207c')

 build() {
    cd "${_name}-${pkgver}"

Fails to build without setuptools and setuptools_scm modules (please add makedepends=python-setuptools-scm).

Here's an updated PKGBUILD for the latest version as of today (2023-10-15):

_name=plotnine
pkgname=python-$_name
pkgver=0.12.3
pkgrel=1
pkgdesc='A grammar of graphics for python'
arch=(any)
url="https://github.com/has2k1/$_name"
license=('MIT')
depends=(
  'python>=3.9'
  'python-matplotlib>=3.6.0'
  'python-mizani<=0.11.0'
  'python-numpy>=1.23.0'
  'python-pandas>=1.5.0'
  'python-patsy>=0.5.1'
  'python-scipy>=1.5.0'
  'python-statsmodels>=0.14.0'
)

optdepends=(
  'python-adjusttext: Library to avoid/minimize text overlaps in plots'
  'python-geopandas: Geospatial data support'
  'python-scikit-learn: gaussian process smoothing, kernel density implementation'
  'python-scikit-misc: loess smoothing'
  'python-shapely: Manipulation and analysis of geometric objects in the Cartesian plane'
)

makedepends=(
  'python-build'
  'python-installer'
  'python-wheel'
)

checkdepends=(
  'python-pytest'
  'python-pytest-cov'
  'python-vcrpy'
)

source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
sha256sums=('a38dcb3607fc003c1e59ae0c9d535dae7817650d1cbc2e56e56e5b3de88dfe99')

# Pytest is pretty heavy
# Skip by default
BUILDENV+=('!check')
_archive="${_name}-${pkgver}"

build() {
  cd "${_archive}"
  python -m build --wheel --no-isolation
}

check() {
  cd "${_archive}"

  # Run pytest
  pytest
}

package() {
  cd "${_archive}"
  python -m installer --destdir="${pkgdir}" dist/*.whl

  install -Dm0644 -t "${pkgdir}/usr/share/licenses/${pkgname}/" LICENSE
}

# vim: sw=2 ts=2 et: