Fixed

# Maintainer: amateurece <ethan.twardy at gmail dot com>

pkgname=sdbusplus-git
pkgver=r868.ed24aa51
pkgrel=1
pkgdesc="C++ bindings for systemd dbus APIs"
url="https://github.com/openbmc/sdbusplus"
arch=('i686' 'x86_64' 'aarch64')
license=('Apache-2.0')
depends=('glibc' 'gcc-libs' 'nlohmann-json' 'systemd-libs' 'python' 'python-jsonschema' 'python-mako' 'python-inflection' 'python-yaml')
makedepends=("boost-libs" "cmake" "git" "meson" "ninja"  "pkgconf" "python-build" "python-installer" "python-setuptools" "python-wheel")
source=("${pkgname}::git+https://github.com/openbmc/sdbusplus.git")
sha256sums=('SKIP')

_meson_setup() {
    arch-meson -Dtests=disabled -Dexamples=disabled "${pkgname}" build
}

prepare() {
    _meson_setup
}

pkgver() {
    cd "${pkgname}"
    echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

build() {
    _meson_setup
    meson compile -C build

    # Python tools
    cd "${pkgname}/tools"
    python -m build --wheel --no-isolation
}

package() {
    meson install -C build --destdir "$pkgdir"
    cd "${pkgname}/tools"
    python -m installer --destdir="$pkgdir" dist/*.whl
}

Thank you for your contribution! I will apply this update some time in the next couple of days.

fixed

# Maintainer: amateurece <ethan.twardy at gmail dot com>

pkgname=sdbusplus-git
pkgver=r845.da8574d5
pkgrel=1
pkgdesc="C++ bindings for systemd dbus APIs"
url="https://github.com/openbmc/sdbusplus"
arch=('i686' 'x86_64' 'aarch64')
license=('Apache')
depends=('systemd-libs' 'python-mako' 'python-inflection' 'python-yaml')
makedepends=("boost-libs" "cmake" "git" "meson" "nlohmann-json" "pkgconf" "python-setuptools")
source=("${pkgname}::git+https://github.com/openbmc/sdbusplus.git")
sha256sums=('SKIP')

_meson_setup() {
arch-meson -Dtests=disabled -Dexamples=disabled "${pkgname}" build
}

prepare() {
_meson_setup
}

pkgver() {
cd "${pkgname}"
echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

build() {
_meson_setup
meson compile -C build

# Python tools
cd "${pkgname}/tools"
python setup.py build
}

package() {
meson install -C build --destdir "$pkgdir"
cd "${pkgname}/tools"
python setup.py install --root="$pkgdir" --optimize=1
}

Hi, I'm compiling this package with devtools and I'm getting the following error about missing nlohmann-json package, can you help me to fix it? Thanks！

==> Retrieving sources...
==> WARNING: Skipping all source file integrity checks.
==> Extracting sources...
-> Creating working copy of sdbusplus-git git repo...
Cloning into 'sdbusplus-git'...
done.
==> Starting prepare()...
+ exec meson setup --prefix /usr --libexecdir lib --sbindir bin --buildtype plain --auto-features enabled --wrap-mode nodownload -D b_pie=true -D python.bytecompile=1 -Dtests=disabled -Dexamples=disabled sdbusplus-git build
The Meson build system
Version: 1.6.0
Source dir: /build/sdbusplus-git/src/sdbusplus-git
Build dir: /build/sdbusplus-git/src/build
Build type: native build
Project name: sdbusplus
Project version: 1.0.0
C compiler for the host machine: cc (gcc 14.2.1 "cc (GCC) 14.2.1 20240910")
C linker for the host machine: cc ld.bfd 2.43.0
C++ compiler for the host machine: c++ (gcc 14.2.1 "c++ (GCC) 14.2.1 20240910")
C++ linker for the host machine: c++ ld.bfd 2.43.0
Host machine cpu family: x86_64
Host machine cpu: x86_64
Found pkg-config: YES (/usr/bin/pkg-config) 2.3.0
Run-time dependency libsystemd found: YES 256
Did not find CMake 'cmake'
Found CMake: NO
Run-time dependency nlohmann_json found: NO (tried pkgconfig and cmake)
Looking for a fallback subproject for the dependency nlohmann_json

sdbusplus-git/meson.build:15:20: ERROR: Automatic wrap-based subproject downloading is disabled

A full log can be found at /build/sdbusplus-git/src/build/meson-logs/meson-log.txt
==> ERROR: A failure occurred in prepare().
Aborting...
==> ERROR: Build failed, check /var/lib/archbuild/extra-x86_64