想要深入使用 Notion 数据库，函数一定是绕不开的话题。它有点像 Excel 里的公式，根据几个单元格的值计算出一个新值，又有点像一些编程语言。12 月 18 日，theBlock 联合 Notion 中文社区举办了一次「和我一起写函数 • Write Formulas With Me」线上直播活动。我们针对宣传期间的问卷调查结果，期望可以让大家收获一些学习函数的方法和解决问题的思路。如果你错过了直播，那不妨跟随我们的文字版记录，一起探索 Notion 数据库函数吧～

函数可以做什么

在 Notion 数据库中新建一列，将属性类型修改为函数（Formula），点击这一列任意一格就会弹出函数编辑窗口，输入 1+1 然后点击 Done，就完成了一个函数的编写，这一列所有值都会显示为 2。

这就是一个简单的函数，但我们显然不满足于让一列函数只显示相同的结果，因此，我们可以调用这个数据库中其他的属性，作为函数属性的值，只需要用 prop("属性名称") 即可。例如在这个水果价格表中，直接用 prop("单价") 获得单价属性的值，你也可以直接在函数编辑窗左侧的选项中点击或回车来插入。

既然可以调用其他属性，我们就能用函数来实现一些运算：例如想要获得每种水果的总价，我们知道只需要 单价 * 数量 即可，因此 prop("单价") * prop("数量") 就能获得每种水果的总价。

这就是一个简单的函数例子，我们对于每一行不同的水果，对不同的单价和数量，用一个相同的函数，得到了每种水果的总价。Notion 数据库中的函数（Formula）就是用相同方法解决多个同类问题。数据库的每一行都是一个独立的问题，但可以用同一个函数解决。不止是数字，文本、日期等等，Notion 中有非常多的函数来解决各种问题。

函数应该怎么写

写好函数，需要遵循一定的语法格式，我们首先来看看函数的组成。函数编辑窗口左侧栏一共分为四大类：属性（Properties）、常量（Constants）、运算符（Operators）、函数（Functions）。

• 属性已经在上文提到，就是数据库中的各种属性，会在这里汇总显示。
• 常量是一个固定的值，例如我们用 1 来表示数字 1，pi 就表示圆周率的值，它们和属性值一样，可以用于函数运算。除了这四个外，直接写出的数字，或者放在双引号中的文本（如 "你好"）都是常量。
• 运算符则是加在各种值之间的符号，表示特定的含义。例如 * 就表示将它前后的两个值相乘。
• 函数（Functions）则具有这样的格式：函数名(值1, 值2, ...)，由函数名和括号中用逗号分隔的值组成，并可以得到一个函数结果。例如想要求平方根，就可以用 sqrt() 函数，sqrt(144) 就会得到 12。每个运算符其实也有函数的写法，例如乘法运算就可以写做 multiply(1, 2) 表示 1*2，可以得到结果 2。

一个完整的函数（Formula）就是以上几个部分相互组合的结果。函数里的值也被称为参数，它可以是一个属性、一个常量或者另一个函数的结果。每个函数往往有指定的参数个数和参数类型，上面我们提到的例子中大多用到数字值，其实还有几种数据类型：文本、日期、布尔值。它们可以应用于不同的函数，产生不同的结果。下面就来认识一下 Notion 函数中用到的 4 种数据类型吧。

不同的数据类型

数据库中的各种属性和常量可归为四种数据类型：数字、文本、日期、布尔值，不同的函数操作和生成的数据类型也不同。

数字

数字的运算可以直接使用加减乘除符号，也可以用 add(1, 3) 这样的方式。如果需要四舍五入、向上取整、向下取整，则可以使用 around(), ceil(), floor() 函数。

文本

对文本类型最常见的操作是文本拼接，只要用 + 就好。需要注意，想直接键入文本内容时，需要放在一对双引号中。例如这个例子里，将英文名、空格、姓氏进行了文本拼接。

日期

日期也是很常用的数据类型。Notion 数据库中，你可以在一格内填入起止日期，这时使用 end() 函数就能获得其中的截止日期。其他一些日期相关的函数将会在案例部分介绍。

布尔

布尔值就是真或假，Notion 函数中会用一个复选框是否打钩代表布尔值。例如想判断数量是否大于 4，就可以直接用 prop("数量") > 4。

一些注意事项

数据类型转换

看下面这个例子，我们想把 A 和 B 列的数字相加求和，却发现报错了，错误提示是数据类型不匹配（Type mismatch），属性 B 不是文本。函数窗口右上角的属性栏确实指示了属性 B 是数字类型，而属性 A 是文本类型，因此当用 + 连接两者时，Notion 不知道该做文本拼接还是数字求和。

解决方法是用 toNumber() 获取到属性 A 的值（文本类型）后再转换为数字类型。

如果我们需要做的是文本拼接，则需要将数字类型转换为文本类型，这时可用 format() 函数。

利用好函数编辑窗口

函数编辑窗口的左侧栏中，每个函数或运算符前的图标指示了这个函数一般生成什么数据类型的结果。当你不知道该用什么函数，或者一个函数怎么用时，提示窗口中的说明、语法、案例往往能帮上大忙。这里以常见的 if() 函数为例进行说明，解决一个判断会员费的问题，初级、中级、高级会员每个月分别为 5 元、10 元、15元。

提示窗口中显示 if() 函数的作用是根据一个值，在某两个值间切换。它有三个参数，第一个是布尔值，布尔值为真时输出第二个值，布尔值为假时输出第三个值。这里第二第三个值没有数据类型的要求，但因为这个值会参与后续运算或直接输出，因此它们必须是同一数据类型。语法中展示了两种不同的写法，效果相同，可以自行选择。

显然一个判断无法解决这个问题，让我们先来判断是否是初级，如果是，显示 5， 不是则显示 555。这里需要注意，当判断两个值是否相等时，需要用两个等号连接，即 prop("等级") == "初级"，如果要判断是否不相等，则需要用 !=。因此第一层判断可以用 if(prop("等级") == "初级", 5, 555)。

随后我们还需要判断是否为中级，是则显示 10，不是则说明是高级，显示 15。这部分的函数是 if(prop("等级") == "中级", 10, 15)，我们把它粘贴到前一个函数中 555 的部分即可

if(prop("等级") == "初级", 5, if(prop("等级") == "中级", 10, 15))

此外，还值得注意的是，不是所有的函数，参数个数都是固定值，例如用于文本截取的函数 slice()，参数个数为 2 或 3 个。必须提供原始文本和开始位置，结束位置不是必给项，如果没有给出则截取到末尾。图中的例子指定开始位置（包括）为 0，结束位置（不包括）为 2，即截取出第 0 位和第 1 位的字母。不少计算机语言的计数都是从 0 开始，而不是 1。

其他的函数在遇到时也都可以通过函数窗口的说明，了解它的用法。

四个实用案例

这里我们还准备了四个案例，其中涉及了不少函数。你可以从这里复制四个案例，跟随我们的思路一起写。完整的数据库及函数写法也会在文末给出。

任务完成百分比

假设每个任务有六个阶段，如何根据勾选状态计算任务完成百分比？这里给出了预期结果，选择了百分比格式，实际上只是一个 0 到 1 之间的数字。为方便理解，也可以先把它选作普通数字格式。

我们首先需要得到每一行有多少个勾选项，就是将布尔值转换为数字类型（0 或 1）再相加。例如是否已执行转换为数字用 toNumber(prop("执行"))。

随后将所有项转换成数字类型再相加就得到了每一行的勾选数，整体除以 6 就可以得到进度值：

(toNumber(prop("发布")) + toNumber(prop("执行")) + toNumber(prop("讨论")) + toNumber(prop("反馈")) + toNumber(prop("完成")) + toNumber(prop("归档"))) / 6

我们希望能保留两位小数，而这个结果与我们预期结果的小数值不同。如果直接用之前介绍的 round() 函数，会保留到整数。根据这个特性，我们可以把结果先放大 100 倍，取整后再缩小到 100 分之 1，即 round(prop("进度值") * 100) / 100。这个方法在我们需要保留几位小数时非常好用。

随后只需要将中间值代入最后的函数中，就可以得到完整的结果，最后再将数字格式改为百分比格式即可。

round((toNumber(prop("发布")) + toNumber(prop("执行")) + toNumber(prop("讨论")) + toNumber(prop("反馈")) + toNumber(prop("完成")) + toNumber(prop("归档"))) / 6 * 100) / 100

总结：在这个案例里我们主要使用了 round(), toNumber() 这两个函数，特别介绍了保留 n 位小数的写法，通用式为：round(prop("属性名称") * 10^n) / (10^n)。 另外还有一个补充小技巧，想要转换为数字类型时，不仅可以用 toNumber() 函数，也可以直接用一个 +（参见 unaryPlus() 函数的说明）

订阅服务的下次付款日期

这是一个简单的订阅服务追踪数据库，通过填入单次金额、首次付款时间和周期，就可以自动计算出月均、年均和下次付款时间等。我们重点来看下次付款时间的计算方法，以月付为例，其他类似。

一拿到这个问题可能有些头大，不如先来想想我们自己如何解决这个问题，再去教给计算机。以第一行为例，从 2021 年 5 月 6 日开始付款，在 2021 年 12 月 27 日的视角下，下次月付时间应当是 2022 年 1 月 6 日。似乎非常简单，但计算机并没有那么聪明。要想教会它，需要把每一步都搞清楚：首次付款到现在，已经过了 7 个多月，因此下次付款在首次付款的 8 个月后。我们只要把这部分写成函数即可。

首次付款到现在的月数：获取现在的时间可用 now() 函数，它不需要输入参数。然后对现在和开始日期使用 dateBetween() 函数，它的三个参数分别是两个日期和指定的时间单位，这里是 "months"：

dateBetween(now(), prop("首次付款"), "months")

首次付款的 n+1 个月后：使用 dateAdd() 函数，它的三个参数分别为日期、数字、时间单位

dateAdd(prop("首次付款"), prop("月数") + 1, "months")

将月数的函数代入就可以得到完整的函数

dateAdd(prop("首次付款"), dateBetween(now(), prop("首次付款"), "months") + 1, "months")

随后只要配合 if() 判断，就可以把年付、季付的情况也包含其中

(prop("周期") == "月") ? dateAdd(prop("首次付款"), dateBetween(now(), prop("首次付款"), "months") + 1, "months") : ((prop("周期") == "季") ? dateAdd(prop("首次付款"), dateBetween(now(), prop("首次付款"), "quarters") + 1, "quarters") : dateAdd(prop("首次付款"), dateBetween(now(), prop("首次付款"), "years") + 1, "years"))

总结：这里主要使用了 if(), now(), dateAdd(), dateBetween() 等函数。函数并不复杂，这个问题的难点主要在于如何想到这样的计算方法，这就需要我们用计算机的思维，一步一步地思考这个问题。

统计个数

我们有时会遇到统计一个单元格内标签或者人数的情况，例如投票。这里介绍的方法对多选、人员、关联关系、汇总等属性都有效，这里以多选属性为例，列出了“人员”和相应的预期个数结果。

我们首先直接用 prop("人员") 来看看这个属性对应的文本内容。发现把每个标签转换成文本后，是用逗号隔开的。

也就是说，有 2 个标签时，就会得到 1 个逗号；有 5 个标签时，就会得到 4 个逗号。那么似乎只要获得逗号个数再加 1 就是标签数了。如何获得逗号个数呢？我们需要用到 replaceAll() 函数。根据提示框中的信息，replaceAll() 函数有 3 个参数 A、B、C，简单来说就是把 A 中所有 B 元素都替换成 C。给的例子就是把所有 - 都替换成了 !。这里我们显然要对 , 下手，我们把逗号替换为空文本试试

replaceAll(prop("人员"), ",", "")

发现文本中所有逗号都被删除了。那么要想得到逗号的个数，就只需要用 length() 函数获得 人员 和 替换逗号 两个属性各自的长度，再相减即可

length(prop("人员")) - length(prop("替换逗号"))

现在似乎只要把长度差 +1 就是最终结果了，但如果我们新建一行，即人员个数为 0，长度差+1 的结果是 1。这是因为人员个数为 0 或 1 的情况下，逗号个数都是 0，两者无法区分。

因此我们需要用 empty() 函数判断人员属性是否为空，空则显示 0，不为空再使用 长度差+1 的结果

if(empty(prop("人员")), 0, prop("长度差+1"))

以上是我们的思考过程，随后我们可以逐一代入，把所有内容合并到一条函数中，其他的函数属性都可以删除。

if(empty(prop("人员")), 0, length(prop("人员")) - length(replaceAll(prop("人员"), ",", "")) + 1)

这个函数还有一种实现方式：我们要获得逗号个数，刚刚使用了总长度减去删除逗号的文本长度，实际上我们可以直接删除其他内容，只保留逗号，这需要用到正则表达式。它是由普通字符和特殊字符组成的一组文本模式，例如这里我们需要匹配所有非逗号内容，就可以用 [^,]。这里的中括号表示匹配里面所有字符，^ 符号表示除了……的所有内容。使用 replaceAll(prop("人员"), "[^,]", "")，将人员属性中除了逗号的内容都替换为空，就可以只留下逗号了：

接下来只要获得这个文本的长度，再配合是否为空，就能得到和刚刚一致的结果，函数如下：

if(empty(prop("人员")), 0, length(replaceAll(prop("人员"), "[^,]", "")) + 1)

我们可以发现后者更短，且只用了两次人员属性，因此在修改时会更方便。因此如果你想把这个方法应用到自己的数据库，可以直接复制后者，修改两处属性名称。

总结：这个案例中，我们使用了 if(), empty(), length(), replaceAll() 这 4 个函数。在遇到文本处理时，replace() 和 replaceAll() 两个函数很常用，配合正则表达式更是能玩出无限可能。

倒数日 / 纪念日

在这个案例中，我们希望根据给定日期，得到距离今天还有几天、已过几天或者就是今天。对于两人的纪念日、活动安排的记录，或者是一个人的代办任务都非常实用，也可以加到刚刚的订阅追踪数据库中。这里我们将明天记为“还有 1 天”，以此类推。在 2021 年 12 月 27 日的视角下，预期结果如下：

这个问题有 3 种结果：还有几天、已过几天或者就是今天，正好对应了正数，负数和零。因此我们可以用一个数字代表最终结果，也就是相差的日期数。这将问题分为两步：得到差值和将它格式化为文本。

首先解决相差日期数，和之前一样，很自然地使用：dateBetween(prop("日期"), now(), "days")。发现已过和今天是我们想要的结果，还有几天却会相差 1。也就是说，对于今天和明天，这个函数的结果都是 0。

为了了解原因，我们将 "days" 改为 "hours"， 会发现今天和明天距离现在的小时数都小于 24，如果都除以 24，就会都小于 1 天，因此都得到了 0 天的结果。这也说明，Notion 中如果日期属性不填入时间，会自动使用当天的凌晨 0 点。

这不是我们想要的结果。为避免得到的天数不是整数，我们可以获取今天 0 点的时刻，再与指定日期比较。今天 0 点可以用现在的时间减去今天过了多少分钟得到，需要用到 dateSubtract() 函数。今天过了多少分钟可以由现在的小时数（hours()）* 60 + 现在的分钟数（minutes()）得到。因此今天 0 点就是

dateSubtract(now(), hour(now()) * 60 + minute(now()), "minutes")

这时再用 dateBetween() 就能得到正确的相差日期数了

dateBetween(prop("日期"), prop("今天0点"), "days")

事实上，上两步的函数可以简化。上一步的日期差可以转换成

dateBetween(prop("日期"), prop("今天0点"), "minutes") / 1440

其中的 1440 是一天的分钟数，两者结果相等。此时代入今天 0 点的函数可以得到

dateBetween(prop("日期"), dateSubtract(now(), hour(now()) * 60 + minute(now()), "minutes"), "minutes") / 1440

我们算时间差和时间相减都用了分钟作为单位，因此可以把时间相减移到外面，直接在计算完时间差后做数字减法，这就是我们获得差值用到的函数：

(dateBetween(prop("日期"), now(), "minutes") + hour(now()) * 60 + minute(now())) / 1440

下一步，我们要把差值格式化为文本。如前文所述，如果我们直接用 "还有 " + prop("差值") 会报错：类型不匹配。这是因为加号连接了文本属性和数字属性，它不知道该做文本拼接还是数字求和。因此我们需要把数字用 format() 函数转换为文本格式

"还有 " + format(prop("差值")) + " 天"

已过部分同理，只要在差值前加上负号

"已过 " + format(-prop("差值")) + " 天"

然后只需要判断差值的正、负和 0，显示不同的文本。先来判断是否为正

if(prop("差值") > 0, prop("还有"), "其他情况")

然后再加上一层 if 来区分是负数还是 0，替换 "其他情况"

if(prop("差值") > 0, prop("还有"), if(prop("差值") < 0, prop("已过"), "就是今天"))

这里如果把前面的函数属性全部代入，会发现差值用了很多次，因此我建议保留差值属性：

(dateBetween(prop("日期"), now(), "minutes") + hour(now()) * 60 + minute(now())) / 1440

再配合以下的两层判断就能得到结果

if(prop("差值") > 0, "还有 " + format(prop("差值")) + " 天", if(prop("差值") < 0, "已过 " + format(-prop("差值")) + " 天", "就是今天"))

总结：我们使用了 if(), now(), hour(), minute(), format(), dateBetween() 等函数，做出了倒数日 / 纪念日的效果。 这里只是提供了一种精确计算日期差值的思路，还有很多方法，例如对于还有几天的数字结果，直接加 1。如果需要，也还可以继续嵌套判断，在时间临近时转为还差多少小时，这就留做课后作业啦。

写在最后

• 如果你的函数很长，可以先在代码块或其他编辑器里写，那样可以换行，甚至检查括号匹配等等。写完后再删除换行，复制到函数窗口里。
• 有些我们一眼就能解决的问题，Notion 函数并无法理解。请把它当作一个 5 岁的孩子，一步一步地告诉它解决方法。
• 报错并不可怕，根据错误尝试解决办法就好，比如不小心用了中文的符号，括号数量没有匹配，参数的数量或数据类型错误，都可能引起报错。如果经常遇到括号不匹配的问题，不如试试在写完函数名后，就在后面加上一对括号，然后再在里面写参数。

函数是数据库的一大利器。只要了解几个数据类型，几个常用函数，就可以上手去写了。逐渐地在尝试中，在报错中，在函数窗口的说明中，你会发现它并没有那么遥不可及。即使没有编程基础，依然可以用好它。

补充

关注 Notion • theBlock 少数派专栏，我们会在这里分享关于 Notion 的更新动向、使用技巧和实用资源。

文中使用的数据库都可以在这个页面找到。想了解更多 Notion 资讯和教程帮助，欢迎访问我和两位 Notion 大使维护的 the-block.club，或订阅 Telegram 频道 @theBlockClub（国内镜像站）。未来的 Notion 相关活动也会在这里更新。

如果你对 Notion 有兴趣，欢迎加入 Telegram 上的 Notion 中文社区。也欢迎访问我的主页 niin.notion.site，了解更多 Notion 使用技巧。