<..========================================================
==                                                       ==
==                Macrobject Nuva Samples                ==
==                                                       ==
==      Copyright (c) 2004-2006 Macrobject Software      ==
==                                                       ==
==                  ALL RIGHTS RESERVED                  ==
==                                                       ==
==               http://www.macrobject.com               ==
==                                                       ==
========================================================..>
<.
// Turtle graphics in Logo language
class Turtle()
  var Aspect = North()

  function Left()
    Aspect = Aspect.Left()
  end function

  function Right()
    Aspect = Aspect.Right()
  end function
  
  function Answer()
    Aspect.Answer()
  end function
  
  class North()
    function Left()
      Result = West()
    end function

    function Right()
      Result = East()
    end function

    function Answer()
      ? ' -> North'
    end function
  end class
  
  class South()
    function Left()
      Result = East()
    end function

    function Right()
      Result = West()
    end function

    function Answer()
      ? ' -> South'
    end function
  end class
  
  class East()
    function Left()
      Result = North()
    end function

    function Right()
      Result = South()
    end function

    function Answer()
      ? ' -> East'
    end function
  end class
  
  class West()
    function Left()
      Result = South()
    end function

    function Right()
      Result = North()
    end function

    function Answer()
      ? ' -> West'
    end function
  end class
end class

// Test
var t = Turtle()
t.Answer()

t.Left()
t.Answer()

t.Left()
t.Answer()

t.Left()
t.Answer()

t.Left()
t.Answer()

t.Right()
t.Answer()

t.Right()
t.Answer()

t.Right()
t.Answer()

t.Right()
t.Answer()
.>

<..
【简介】
    本例是一个设计模式范例程序：状态机模式。
   
    大家或许都还记得 Logo 语言中的海龟图，Logo 程序命令海龟拿着笔不停的转、到处画，结果画出了很多奇妙的图形。
   
    这只海龟一刻不停的转，总是很担心它会转晕，因此，本例给这只海龟增强了一个状态机，随时记下海龟转过的方向，因而，它再也不会转晕了。
   
    当然了，这只是个范例，主要为了演示状态机设计模式。

【看点】
    1、本例给出了海龟的一个类：Turtle，它有如下的几个方法：
       Left：  左转
       Right： 右转
       Answer：回答现在面对的方向
      
       本例中为海龟配置了一个状态机，其中有四个状态，分别是：North、South、East、West
       海龟通过将以上的三个方法委托给自己的状态机来运行，每个状态机完成正确的状态切换，以及作出正确的回答。
      
    2、本例最后测试了一下这个海龟，让它转了几下，同时叫它回答方向，结果，都对了。

【扩展】
    本例只是设计模式的范例程序，可以改造成真正的状态机程序。
..>

本例运行结果如下：

 -> North -> West -> South -> East -> North -> East -> South -> West -> North